convert-modeswitch.pl

   1 #!/usr/bin/perl
   2 use strict;
   3
   4 my $msg_ctr = 0;
   5 my %messages;
   6 my %devices;
   7
   8 sub add_message {
   9         my $msg = shift;
  10         my $val = $messages{$msg};
  11
  12         defined($val) or do {
  13                 $val = $msg_ctr++;
  14                 $messages{$msg} = $val;
  15         };
  16
  17         return $val;
  18 }
  19
  20 sub add_device($) {
  21         my $id = shift;
  22         my $dev = {};
  23         my $match;
  24
  25         $id =~ /^(\w{4}:\w{4})(:.*)?/ or do {
  26                 warn "Invalid device ID string $id\n";
  27                 return $dev;
  28         };
  29
  30         $id = $1;
  31         $match = $2 or $match = "*";
  32
  33         $devices{$id} or $devices{$id} = {};
  34         $devices{$id}->{$match} = $dev;
  35
  36         return $dev;
  37 }
  38
  39 sub add_hex {
  40         $_[0] =~ s/^0x//;
  41         return hex($_[0]);
  42 }
  43
  44 sub add_mode {
  45         $_[1] =~ s/^(\w+)Mode$/$1/;
  46         return $_[1];
  47 }
  48
  49 my $hex_option = [ undef, \&add_hex ];
  50 my $msg_option = [ undef, \&add_message ];
  51 my $mode_option = [ "Mode", \&add_mode ];
  52 my %options = (
  53         TargetVendor => $hex_option,
  54         TargetProductList => [ "TargetProduct", sub { return [ map(hex,split(/,/, $_[0])) ]; } ],
  55         TargetProduct => [ "TargetProduct", sub { return [ hex($_[0]) ]; } ],
  56         TargetClass => $hex_option,
  57         MessageContent => $msg_option,
  58         MessageContent2 => $msg_option,
  59         MessageContent3 => $msg_option,
  60         WaitBefore => [ ],
  61         DetachStorageOnly => [ ],
  62         MBIM => $mode_option,
  63         HuaweiMode => $mode_option,
  64         HuaweiNewMode => $mode_option,
  65         OptionMode => $mode_option,
  66         SierraMode => $mode_option,
  67         SonyMode => $mode_option,
  68         QisdaMode => $mode_option,
  69         GCTMode => $mode_option,
  70         KobilMode => $mode_option,
  71         SequansMode => $mode_option,
  72         MobileActionMode => $mode_option,
  73         CiscoMode => $mode_option,
  74         StandardEject => $mode_option,
  75         NoDriverLoading => [],
  76         MessageEndpoint => $hex_option,
  77         ReleaseDelay => [],
  78         NeedResponse => [],
  79         ResponseEndpoint => $hex_option,
  80         ResetUSB => [],
  81         InquireDevice => [],
  82         CheckSuccess => $hex_option,
  83         Interface => $hex_option,
  84         Configuration => $hex_option,
  85         AltSetting => $hex_option,
  86 );
  87
  88 sub parse_file($) {
  89         my $file = shift;
  90         my $id;
  91
  92         $id = $file;
  93         $file =~ /\/?([^\/]+)$/ and $id = $1;
  94
  95         my $dev = add_device($id);
  96
  97         open FILE, "<$file" or die "Cannot open file '$file'\n";
  98         while (<FILE>) {
  99                 chomp;
 100                 s/^\s*(.+?)\s*$/$1/;
 101                 s/#.+$//;
 102                 next unless /\w/;
 103                 /(\w+)\s*=\s*(.+)\s*/ or do {
 104                         warn "Invalid Line: $_";
 105                         next;
 106                 };
 107
 108                 my ($var, $val) = ($1, $2);
 109                 $val =~ s/^"(.+)"$/$1/;
 110
 111                 my $opt = $options{$var};
 112                 $opt or do {
 113                         warn "Unrecognized option $var in file $file\n";
 114                         next;
 115                 };
 116
 117                 $opt->[1] and $val = &{$opt->[1]}($val, $var);
 118                 $opt->[0] and $var = $opt->[0];
 119                 $dev->{$var} = $val;
 120         }
 121 }
 122
 123 foreach my $file (@ARGV) {
 124         parse_file $file;
 125 }
 126
 127 sub json_chr {
 128         my $chr = shift;
 129
 130         $chr eq "\b" and return "\\b";
 131         $chr eq "\n" and return "\\n";
 132         $chr eq "\r" and return "\\r";
 133         $chr eq "\t" and return "\\t";
 134         $chr eq "\\" and return "\\\\";
 135         $chr eq "\"" and return "\\\"";
 136         $chr eq '/' and return "\\/";
 137         return sprintf("\\u%04x", ord($chr));
 138 };
 139
 140 sub json_str {
 141         $_[0] =~ s/([\x00- \/"\\])/json_chr($1)/eg;
 142         return $_[0];
 143 }
 144
 145 sub json_val($$) {
 146         my ($val, $type) = (shift, shift);
 147         $type eq 'bool' and $val = $val > 0 ? "true" : "false";
 148         $type eq 'string' and $val = "\"$val\"";
 149         return $val;
 150 }
 151
 152 sub dev_opt {
 153         my ($val, $name, $type, $sep) = (shift, shift, shift, shift);
 154         return unless defined($val);
 155         if ($type =~ /array:(.+)/) {
 156                 $type = $1;
 157                 my @val = @$val;
 158                 undef $val;
 159                 foreach my $elem (@val) {
 160                         my $json = json_val($elem, $type);
 161                         next unless defined $json;
 162                         if (defined $val) {
 163                                 $val = "$val, $json"
 164                         } else {
 165                                 $val = $json;
 166                         }
 167                 }
 168                 $val = "[ $val ]";
 169         } else {
 170                 $val = json_val($val, $type);
 171         }
 172         print "$$sep\t\t\t\t\"".json_str($name)."\": $val";
 173         $$sep = ",\n";
 174 }
 175
 176 print <<EOF;
 177 {
 178         "messages" : [
 179 EOF
 180 my $suffix = "";
 181 foreach my $msg (sort { $messages{$a} <=> $messages{$b} } keys %messages) {
 182         print "$suffix\t\t\"".json_str($msg)."\"";
 183         $suffix = ",\n";
 184 }
 185 print <<EOF;
 186
 187         ],
 188
 189         "devices" : {
 190 EOF
 191 my $dev_sep = "";
 192 foreach my $devid (sort keys %devices) {
 193         my $dev = $devices{$devid};
 194
 195         print "$dev_sep\t\t\"".json_str($devid)."\": {\n";
 196         $dev_sep = ",\n";
 197
 198         my $match_sep = "";
 199         foreach my $match (sort keys %$dev) {
 200                 my $cur = $dev->{$match};
 201                 my $sep = "";
 202
 203                 print "$match_sep\t\t\t\"".json_str($match)."\": {\n";
 204                 $match_sep = ",\n";
 205
 206                 dev_opt($cur->{TargetVendor}, "t_vendor", "int", \$sep);
 207                 dev_opt($cur->{TargetProduct}, "t_product", "array:int", \$sep);
 208                 dev_opt($cur->{TargetClass}, "t_class", "int", \$sep);
 209                 dev_opt($cur->{DetachStorageOnly}, "detach_storage", "bool", \$sep);
 210                 dev_opt($cur->{Mode}, "mode", "string", \$sep);
 211                 dev_opt($cur->{NoDriverLoading}, "no_driver", "bool", \$sep);
 212                 dev_opt($cur->{MessageEndpoint}, "msg_endpoint", "int", \$sep);
 213                 my $msg = [
 214                         $cur->{MessageContent},
 215                         $cur->{MessageContent2},
 216                         $cur->{MessageContent3}
 217                 ];
 218                 dev_opt($msg, "msg", "array:int", \$sep);
 219                 dev_opt($cur->{WaitBefore}, "wait", "int", \$sep);
 220                 dev_opt($cur->{ReleaseDelay}, "release_delay", "int", \$sep);
 221                 dev_opt($cur->{NeedResponse}, "response", "bool", \$sep);
 222                 dev_opt($cur->{ResponseEndpoint}, "response_endpoint", "int", \$sep);
 223                 dev_opt($cur->{ResetUSB}, "reset", "bool", \$sep);
 224                 dev_opt($cur->{InquireDevice}, "inquire", "int", \$sep);
 225                 dev_opt($cur->{CheckSuccess}, "check", "bool", \$sep);
 226                 dev_opt($cur->{Interface}, "interface", "int", \$sep);
 227                 dev_opt($cur->{Configuration}, "config", "int", \$sep);
 228                 dev_opt($cur->{AltSetting}, "alt", "int", \$sep);
 229                 print "\n\t\t\t}";
 230         }
 231         print "\n\t\t}"
 232 }
 233 print <<EOF;
 234
 235         }
 236 }
 237 EOF