scripts/package-metadata.pl

   1 #!/usr/bin/env perl
   2 use FindBin;
   3 use lib "$FindBin::Bin";
   4 use strict;
   5 use metadata;
   6 use Getopt::Long;
   7
   8 my %board;
   9
  10 sub version_to_num($) {
  11         my $str = shift;
  12         my $num = 0;
  13
  14         if (defined($str) && $str =~ /^\d+(?:\.\d+)+$/)
  15         {
  16                 my @n = (split(/\./, $str), 0, 0, 0, 0);
  17                 $num = ($n[0] << 24) | ($n[1] << 16) | ($n[2] << 8) | $n[3];
  18         }
  19
  20         return $num;
  21 }
  22
  23 sub version_filter_list(@) {
  24         my $cmpver = version_to_num(shift @_);
  25         my @items;
  26
  27         foreach my $item (@_)
  28         {
  29                 if ($item =~ s/@(lt|le|gt|ge|eq|ne)(\d+(?:\.\d+)+)\b//)
  30                 {
  31                         my $op = $1;
  32                         my $symver = version_to_num($2);
  33
  34                         if ($symver > 0 && $cmpver > 0)
  35                         {
  36                                 next unless (($op eq 'lt' && $cmpver <  $symver) ||
  37                                              ($op eq 'le' && $cmpver <= $symver) ||
  38                                              ($op eq 'gt' && $cmpver >  $symver) ||
  39                                              ($op eq 'ge' && $cmpver >= $symver) ||
  40                                              ($op eq 'eq' && $cmpver == $symver) ||
  41                                              ($op eq 'ne' && $cmpver != $symver));
  42                         }
  43                 }
  44
  45                 push @items, $item;
  46         }
  47
  48         return @items;
  49 }
  50
  51 sub gen_kconfig_overrides() {
  52         my %config;
  53         my %kconfig;
  54         my $package;
  55         my $pkginfo = shift @ARGV;
  56         my $cfgfile = shift @ARGV;
  57         my $patchver = shift @ARGV;
  58
  59         # parameter 2: build system config
  60         open FILE, "<$cfgfile" or return;
  61         while (<FILE>) {
  62                 /^(CONFIG_.+?)=(.+)$/ and $config{$1} = 1;
  63         }
  64         close FILE;
  65
  66         # parameter 1: package metadata
  67         open FILE, "<$pkginfo" or return;
  68         while (<FILE>) {
  69                 /^Package:\s*(.+?)\s*$/ and $package = $1;
  70                 /^Kernel-Config:\s*(.+?)\s*$/ and do {
  71                         my @config = split /\s+/, $1;
  72                         foreach my $config (version_filter_list($patchver, @config)) {
  73                                 my $val = 'm';
  74                                 my $override;
  75                                 if ($config =~ /^(.+?)=(.+)$/) {
  76                                         $config = $1;
  77                                         $override = 1;
  78                                         $val = $2;
  79                                 }
  80                                 if ($config{"CONFIG_PACKAGE_$package"} and ($config ne 'n')) {
  81                                         next if $kconfig{$config} eq 'y';
  82                                         $kconfig{$config} = $val;
  83                                 } elsif (!$override) {
  84                                         $kconfig{$config} or $kconfig{$config} = 'n';
  85                                 }
  86                         }
  87                 };
  88         };
  89         close FILE;
  90
  91         foreach my $kconfig (sort keys %kconfig) {
  92                 if ($kconfig{$kconfig} eq 'n') {
  93                         print "# $kconfig is not set\n";
  94                 } else {
  95                         print "$kconfig=$kconfig{$kconfig}\n";
  96                 }
  97         }
  98 }
  99
 100 my %dep_check;
 101 sub __find_package_dep($$) {
 102         my $pkg = shift;
 103         my $name = shift;
 104         my $deps = $pkg->{depends};
 105
 106         return 0 unless defined $deps;
 107         foreach my $vpkg (@{$deps}) {
 108                 foreach my $dep (@{$vpackage{$vpkg}}) {
 109                         next if $dep_check{$dep->{name}};
 110                         $dep_check{$dep->{name}} = 1;
 111                         return 1 if $dep->{name} eq $name;
 112                         return 1 if (__find_package_dep($dep, $name) == 1);
 113                 }
 114         }
 115         return 0;
 116 }
 117
 118 # wrapper to avoid infinite recursion
 119 sub find_package_dep($$) {
 120         my $pkg = shift;
 121         my $name = shift;
 122
 123         %dep_check = ();
 124         return __find_package_dep($pkg, $name);
 125 }
 126
 127 sub package_depends($$) {
 128         my $a = shift;
 129         my $b = shift;
 130         my $ret;
 131
 132         return 0 if ($a->{submenu} ne $b->{submenu});
 133         if (find_package_dep($a, $b->{name}) == 1) {
 134                 $ret = 1;
 135         } elsif (find_package_dep($b, $a->{name}) == 1) {
 136                 $ret = -1;
 137         } else {
 138                 return 0;
 139         }
 140         return $ret;
 141 }
 142
 143 sub mconf_depends {
 144         my $pkgname = shift;
 145         my $depends = shift;
 146         my $only_dep = shift;
 147         my $res;
 148         my $dep = shift;
 149         my $seen = shift;
 150         my $parent_condition = shift;
 151         $dep or $dep = {};
 152         $seen or $seen = {};
 153         my @t_depends;
 154
 155         $depends or return;
 156         my @depends = @$depends;
 157         foreach my $depend (@depends) {
 158                 my $m = "depends on";
 159                 my $flags = "";
 160                 $depend =~ s/^([@\+]+)// and $flags = $1;
 161                 my $condition = $parent_condition;
 162
 163                 $depend = $2 if $depend =~ /^(.+):(.+)$/ and $dep->{$1} eq 'select';
 164
 165                 next if $condition eq $depend;
 166                 next if $seen->{"$parent_condition:$depend"};
 167                 next if $seen->{":$depend"};
 168                 $seen->{"$parent_condition:$depend"} = 1;
 169                 if ($depend =~ /^(.+):(.+)$/) {
 170                         if ($1 ne "PACKAGE_$pkgname") {
 171                                 if ($condition) {
 172                                         $condition = "$condition && $1";
 173                                 } else {
 174                                         $condition = $1;
 175                                 }
 176                         }
 177                         $depend = $2;
 178                 }
 179                 if ($flags =~ /\+/) {
 180                         my $vdep = $vpackage{$depend};
 181                         if ($vdep) {
 182                                 my @vdeps;
 183
 184                                 foreach my $v (@$vdep) {
 185                                         next if $v->{buildonly};
 186                                         if ($v->{variant_default}) {
 187                                                 unshift @vdeps, $v->{name};
 188                                         } else {
 189                                                 push @vdeps, $v->{name};
 190                                         }
 191                                 }
 192
 193                                 $depend = shift @vdeps;
 194
 195                                 if (@vdeps > 1) {
 196                                         $condition = ($condition ? "$condition && " : '') . join("&&", map { "PACKAGE_$_<PACKAGE_$pkgname" } @vdeps);
 197                                 } elsif (@vdeps > 0) {
 198                                         $condition = ($condition ? "$condition && " : '') . "PACKAGE_${vdeps[0]}<PACKAGE_$pkgname";
 199                                 }
 200                         }
 201
 202                         # Menuconfig will not treat 'select FOO' as a real dependency
 203                         # thus if FOO depends on other config options, these dependencies
 204                         # will not be checked. To fix this, we simply emit all of FOO's
 205                         # depends here as well.
 206                         $package{$depend} and push @t_depends, [ $package{$depend}->{depends}, $condition ];
 207
 208                         $m = "select";
 209                         next if $only_dep;
 210
 211                         $flags =~ /@/ or $depend = "PACKAGE_$depend";
 212                 } else {
 213                         my $vdep = $vpackage{$depend};
 214                         if ($vdep && @$vdep > 0) {
 215                                 $depend = join("||", map { "PACKAGE_".$_->{name} } @$vdep);
 216                         } else {
 217                                 $flags =~ /@/ or $depend = "PACKAGE_$depend";
 218                         }
 219                 }
 220
 221                 if ($condition) {
 222                         if ($m =~ /select/) {
 223                                 next if $depend eq $condition;
 224                                 $depend = "$depend if $condition";
 225                         } else {
 226                                 next if $dep->{"$depend if $condition"};
 227                                 $depend = "!($condition) || $depend" unless $dep->{$condition} eq 'select';
 228                         }
 229                 }
 230                 $dep->{$depend} =~ /select/ or $dep->{$depend} = $m;
 231         }
 232
 233         foreach my $tdep (@t_depends) {
 234                 mconf_depends($pkgname, $tdep->[0], 1, $dep, $seen, $tdep->[1]);
 235         }
 236
 237         foreach my $depend (sort keys %$dep) {
 238                 my $m = $dep->{$depend};
 239                 $res .= "\t\t$m $depend\n";
 240         }
 241         return $res;
 242 }
 243
 244 sub mconf_conflicts {
 245         my $pkgname = shift;
 246         my $depends = shift;
 247         my $res = "";
 248
 249         foreach my $depend (@$depends) {
 250                 next unless $package{$depend};
 251                 $res .= "\t\tdepends on m || (PACKAGE_$depend != y)\n";
 252         }
 253         return $res;
 254 }
 255
 256 sub print_package_config_category($) {
 257         my $cat = shift;
 258         my %menus;
 259         my %menu_dep;
 260
 261         return unless $category{$cat};
 262
 263         print "menu \"$cat\"\n\n";
 264         my %spkg = %{$category{$cat}};
 265
 266         foreach my $spkg (sort {uc($a) cmp uc($b)} keys %spkg) {
 267                 foreach my $pkg (@{$spkg{$spkg}}) {
 268                         next if $pkg->{buildonly};
 269                         my $menu = $pkg->{submenu};
 270                         if ($menu) {
 271                                 $menu_dep{$menu} or $menu_dep{$menu} = $pkg->{submenudep};
 272                         } else {
 273                                 $menu = 'undef';
 274                         }
 275                         $menus{$menu} or $menus{$menu} = [];
 276                         push @{$menus{$menu}}, $pkg;
 277                 }
 278         }
 279         my @menus = sort {
 280                 ($a eq 'undef' ?  1 : 0) or
 281                 ($b eq 'undef' ? -1 : 0) or
 282                 ($a cmp $b)
 283         } keys %menus;
 284
 285         foreach my $menu (@menus) {
 286                 my @pkgs = sort {
 287                         package_depends($a, $b) or
 288                         ($a->{name} cmp $b->{name})
 289                 } @{$menus{$menu}};
 290                 if ($menu ne 'undef') {
 291                         $menu_dep{$menu} and print "if $menu_dep{$menu}\n";
 292                         print "menu \"$menu\"\n";
 293                 }
 294                 foreach my $pkg (@pkgs) {
 295                         next if $pkg->{src}{ignore};
 296                         my $title = $pkg->{name};
 297                         my $c = (72 - length($pkg->{name}) - length($pkg->{title}));
 298                         if ($c > 0) {
 299                                 $title .= ("." x $c). " ". $pkg->{title};
 300                         }
 301                         $title = "\"$title\"";
 302                         print "\t";
 303                         $pkg->{menu} and print "menu";
 304                         print "config PACKAGE_".$pkg->{name}."\n";
 305                         $pkg->{hidden} and $title = "";
 306                         print "\t\t".($pkg->{tristate} ? 'tristate' : 'bool')." $title\n";
 307                         print "\t\tdefault y if DEFAULT_".$pkg->{name}."\n";
 308                         unless ($pkg->{hidden}) {
 309                                 my @def = ("ALL");
 310                                 if (!exists($pkg->{repository})) {
 311                                         push @def, "ALL_NONSHARED";
 312                                 }
 313                                 if ($pkg->{name} =~ /^kmod-/) {
 314                                         push @def, "ALL_KMODS";
 315                                 }
 316                                 $pkg->{default} ||= "m if " . join("||", @def);
 317                         }
 318                         if ($pkg->{default}) {
 319                                 foreach my $default (split /\s*,\s*/, $pkg->{default}) {
 320                                         print "\t\tdefault $default\n";
 321                                 }
 322                         }
 323                         print mconf_depends($pkg->{name}, $pkg->{depends}, 0);
 324                         print mconf_depends($pkg->{name}, $pkg->{mdepends}, 0);
 325                         print mconf_conflicts($pkg->{name}, $pkg->{conflicts});
 326                         print "\t\thelp\n";
 327                         print $pkg->{description};
 328                         print "\n";
 329
 330                         $pkg->{config} and print $pkg->{config}."\n";
 331                 }
 332                 if ($menu ne 'undef') {
 333                         print "endmenu\n";
 334                         $menu_dep{$menu} and print "endif\n";
 335                 }
 336         }
 337         print "endmenu\n\n";
 338
 339         undef $category{$cat};
 340 }
 341
 342 sub print_package_overrides() {
 343         keys %overrides > 0 or return;
 344         print "\tconfig OVERRIDE_PKGS\n";
 345         print "\t\tstring\n";
 346         print "\t\tdefault \"".join(" ", sort keys %overrides)."\"\n\n";
 347 }
 348
 349 sub gen_package_config() {
 350         parse_package_metadata($ARGV[0]) or exit 1;
 351         print "menuconfig IMAGEOPT\n\tbool \"Image configuration\"\n\tdefault n\n";
 352         print "source \"package/*/image-config.in\"\n";
 353         if (scalar glob "package/feeds/*/*/image-config.in") {
 354             print "source \"package/feeds/*/*/image-config.in\"\n";
 355         }
 356         print_package_config_category 'Base system';
 357         foreach my $cat (sort {uc($a) cmp uc($b)} keys %category) {
 358                 print_package_config_category $cat;
 359         }
 360         print_package_overrides();
 361 }
 362
 363 sub and_condition($) {
 364         my $condition = shift;
 365         my @spl_and = split('\&\&', $condition);
 366         if (@spl_and == 1) {
 367                 return "\$(CONFIG_$spl_and[0])";
 368         }
 369         return "\$(and " . join (',', map("\$(CONFIG_$_)", @spl_and)) . ")";
 370 }
 371
 372 sub gen_condition ($) {
 373         my $condition = shift;
 374         # remove '!()', just as include/package-ipkg.mk does
 375         $condition =~ s/[()!]//g;
 376         return join("", map(and_condition($_), split('\|\|', $condition)));
 377 }
 378
 379 sub get_conditional_dep($$) {
 380         my $condition = shift;
 381         my $depstr = shift;
 382         if ($condition) {
 383                 if ($condition =~ /^!(.+)/) {
 384                         return "\$(if " . gen_condition($1) . ",,$depstr)";
 385                 } else {
 386                         return "\$(if " . gen_condition($condition) . ",$depstr)";
 387                 }
 388         } else {
 389                 return $depstr;
 390         }
 391 }
 392
 393 sub gen_package_mk() {
 394         my $line;
 395
 396         parse_package_metadata($ARGV[0]) or exit 1;
 397         foreach my $srcname (sort {uc($a) cmp uc($b)} keys %srcpackage) {
 398                 my $src = $srcpackage{$srcname};
 399                 my $variant_default;
 400                 my %deplines = ('' => {});
 401
 402                 foreach my $pkg (@{$src->{packages}}) {
 403                         foreach my $dep (@{$pkg->{depends}}) {
 404                                 next if ($dep =~ /@/);
 405
 406                                 my $condition;
 407
 408                                 $dep =~ s/\+//g;
 409                                 if ($dep =~ /^(.+):(.+)/) {
 410                                         $condition = $1;
 411                                         $dep = $2;
 412                                 }
 413
 414                                 my $vpkg_dep = $vpackage{$dep};
 415                                 unless (defined $vpkg_dep) {
 416                                         warn sprintf "WARNING: Makefile '%s' has a dependency on '%s', which does not exist\n",
 417                                                 $src->{makefile}, $dep;
 418                                         next;
 419                                 }
 420
 421                                 # Filter out self-depends
 422                                 my @vdeps = grep { $srcname ne $_->{src}{name} } @{$vpkg_dep};
 423
 424                                 foreach my $vdep (@vdeps) {
 425                                         my $depstr = sprintf '$(curdir)/%s/compile', $vdep->{src}{path};
 426                                         if (@vdeps > 1) {
 427                                                 $depstr = sprintf '$(if $(CONFIG_PACKAGE_%s),%s)', $vdep->{name}, $depstr;
 428                                         }
 429                                         my $depline = get_conditional_dep($condition, $depstr);
 430                                         if ($depline) {
 431                                                 $deplines{''}{$depline}++;
 432                                         }
 433                                 }
 434                         }
 435
 436                         my $config = '';
 437                         $config = sprintf '$(CONFIG_PACKAGE_%s)', $pkg->{name} unless $pkg->{buildonly};
 438
 439                         $pkg->{prereq} and printf "prereq-%s += %s\n", $config, $src->{path};
 440
 441                         next if $pkg->{buildonly};
 442
 443                         printf "package-%s += %s\n", $config, $src->{path};
 444
 445                         if ($pkg->{variant}) {
 446                                 if (!defined($variant_default) or $pkg->{variant_default}) {
 447                                         $variant_default = $pkg->{variant};
 448                                 }
 449                                 printf "\$(curdir)/%s/variants += \$(if %s,%s)\n", $src->{path}, $config, $pkg->{variant};
 450                         }
 451                 }
 452
 453                 if (defined($variant_default)) {
 454                         printf "\$(curdir)/%s/default-variant := %s\n", $src->{path}, $variant_default;
 455                 }
 456
 457                 unless (grep {!$_->{buildonly}} @{$src->{packages}}) {
 458                         printf "package- += %s\n", $src->{path};
 459                 }
 460
 461                 if (@{$src->{buildtypes}} > 0) {
 462                         printf "buildtypes-%s = %s\n", $src->{path}, join(' ', @{$src->{buildtypes}});
 463                 }
 464
 465                 foreach my $type ('', @{$src->{buildtypes}}) {
 466                         my $suffix = '';
 467
 468                         $suffix = "/$type" if $type;
 469
 470                         next unless $src->{"builddepends$suffix"};
 471
 472                         defined $deplines{$suffix} or $deplines{$suffix} = {};
 473
 474                         foreach my $dep (@{$src->{"builddepends$suffix"}}) {
 475                                 my $depsuffix = "";
 476                                 my $deptype = "";
 477                                 my $condition;
 478
 479                                 if ($dep =~ /^(.+):(.+)/) {
 480                                         $condition = $1;
 481                                         $dep = $2;
 482                                 }
 483                                 if ($dep =~ /^(.+)\/(.+)/) {
 484                                         $dep = $1;
 485                                         $deptype = $2;
 486                                         $depsuffix = "/$2";
 487                                 }
 488
 489                                 next if $srcname.$suffix eq $dep.$depsuffix;
 490
 491                                 my $src_dep = $srcpackage{$dep};
 492                                 unless (defined($src_dep) && (!$deptype || grep { $_ eq $deptype } @{$src_dep->{buildtypes}})) {
 493                                         warn sprintf "WARNING: Makefile '%s' has a build dependency on '%s', which does not exist\n",
 494                                                 $src->{makefile}, $dep.$depsuffix;
 495                                         next;
 496                                 }
 497
 498                                 my $depstr = sprintf '$(curdir)/%s/compile', $src_dep->{path}.$depsuffix;
 499                                 my $depline = get_conditional_dep($condition, $depstr);
 500                                 if ($depline) {
 501                                         $deplines{$suffix}{$depline}++;
 502                                 }
 503                         }
 504                 }
 505
 506                 foreach my $suffix (sort keys %deplines) {
 507                         my $depline = join(" ", sort keys %{$deplines{$suffix}});
 508                         if ($depline) {
 509                                 $line .= sprintf "\$(curdir)/%s/compile += %s\n", $src->{path}.$suffix, $depline;
 510                         }
 511                 }
 512         }
 513
 514         if ($line ne "") {
 515                 print "\n$line";
 516         }
 517 }
 518
 519 sub gen_package_source() {
 520         parse_package_metadata($ARGV[0]) or exit 1;
 521         foreach my $name (sort {uc($a) cmp uc($b)} keys %package) {
 522                 my $pkg = $package{$name};
 523                 if ($pkg->{name} && $pkg->{source}) {
 524                         print "$pkg->{name}: ";
 525                         print "$pkg->{source}\n";
 526                 }
 527         }
 528 }
 529
 530 sub gen_package_auxiliary() {
 531         parse_package_metadata($ARGV[0]) or exit 1;
 532         foreach my $name (sort {uc($a) cmp uc($b)} keys %package) {
 533                 my $pkg = $package{$name};
 534                 if ($pkg->{name} && $pkg->{repository}) {
 535                         print "Package/$name/subdir = $pkg->{repository}\n";
 536                 }
 537                 my %depends;
 538                 foreach my $dep (@{$pkg->{depends} || []}) {
 539                         if ($dep =~ m!^\+?(?:[^:]+:)?([^@]+)$!) {
 540                                 $depends{$1}++;
 541                         }
 542                 }
 543                 my @depends = sort keys %depends;
 544                 if (@depends > 0) {
 545                         foreach my $n (@{$pkg->{provides}}) {
 546                                 print "Package/$n/depends = @depends\n";
 547                         }
 548                 }
 549         }
 550 }
 551
 552 sub gen_package_license($) {
 553         my $level = shift;
 554         parse_package_metadata($ARGV[0]) or exit 1;
 555         foreach my $name (sort {uc($a) cmp uc($b)} keys %package) {
 556                 my $pkg = $package{$name};
 557                 if ($pkg->{name}) {
 558                         if ($pkg->{license}) {
 559                                 print "$pkg->{name}: ";
 560                                 print "$pkg->{license}\n";
 561                                 if ($pkg->{licensefiles} && $level == 0) {
 562                                         print "\tFiles: $pkg->{licensefiles}\n";
 563                                 }
 564                         } else {
 565                                 if ($level == 1) {
 566                                         print "$pkg->{name}: Missing license! ";
 567                                         print "Please fix $pkg->{src}{makefile}\n";
 568                                 }
 569                         }
 570                 }
 571         }
 572 }
 573
 574 sub gen_version_filtered_list() {
 575         foreach my $item (version_filter_list(@ARGV)) {
 576                 print "$item\n";
 577         }
 578 }
 579
 580 sub gen_usergroup_list() {
 581         parse_package_metadata($ARGV[0]) or exit 1;
 582         for my $name (keys %usernames) {
 583                 print "user $name $usernames{$name}{id} $usernames{$name}{makefile}\n";
 584         }
 585         for my $name (keys %groupnames) {
 586                 print "group $name $groupnames{$name}{id} $groupnames{$name}{makefile}\n";
 587         }
 588 }
 589
 590 sub gen_package_manifest_json() {
 591         my $json;
 592         parse_package_metadata($ARGV[0]) or exit 1;
 593         foreach my $name (sort {uc($a) cmp uc($b)} keys %package) {
 594                 my %depends;
 595                 my $pkg = $package{$name};
 596                 foreach my $dep (@{$pkg->{depends} || []}) {
 597                         if ($dep =~ m!^\+?(?:[^:]+:)?([^@]+)$!) {
 598                                 $depends{$1}++;
 599                         }
 600                 }
 601                 my @depends = sort keys %depends;
 602                 my $pkg_deps = join ' ', map { qq/"$_",/ } @depends;
 603                 $pkg_deps =~ s/\,$//;
 604
 605                 my $pkg_maintainer = join ' ', map { qq/"$_",/ } @{$pkg->{maintainer} || []};
 606                 $pkg_maintainer =~ s/\,$//;
 607
 608                 $json = <<"END_JSON";
 609 ${json}{
 610 "name":"$name",
 611 "version":"$pkg->{version}",
 612 "category":"$pkg->{category}",
 613 "license":"$pkg->{license}",
 614 "maintainer": [$pkg_maintainer],
 615 "depends":[$pkg_deps]},
 616 END_JSON
 617         }
 618
 619         $json =~ s/[\n\r]//g;
 620         $json =~ s/\,$//;
 621         print "[$json]";
 622 }
 623
 624 sub parse_command() {
 625         GetOptions("ignore=s", \@ignore);
 626         my $cmd = shift @ARGV;
 627         for ($cmd) {
 628                 /^mk$/ and return gen_package_mk();
 629                 /^config$/ and return gen_package_config();
 630                 /^kconfig/ and return gen_kconfig_overrides();
 631                 /^source$/ and return gen_package_source();
 632                 /^pkgaux$/ and return gen_package_auxiliary();
 633                 /^pkgmanifestjson$/ and return gen_package_manifest_json();
 634                 /^license$/ and return gen_package_license(0);
 635                 /^licensefull$/ and return gen_package_license(1);
 636                 /^usergroup$/ and return gen_usergroup_list();
 637                 /^version_filter$/ and return gen_version_filtered_list();
 638         }
 639         die <<EOF
 640 Available Commands:
 641         $0 mk [file]                            Package metadata in makefile format
 642         $0 config [file]                        Package metadata in Kconfig format
 643         $0 kconfig [file] [config] [patchver]   Kernel config overrides
 644         $0 source [file]                        Package source file information
 645         $0 pkgaux [file]                        Package auxiliary variables in makefile format
 646         $0 pkgmanifestjson [file]               Package manifests in JSON format
 647         $0 license [file]                       Package license information
 648         $0 licensefull [file]                   Package license information (full list)
 649         $0 usergroup [file]                     Package usergroup allocation list
 650         $0 version_filter [patchver] [list...]  Filter list of version tagged strings
 651
 652 Options:
 653         --ignore <name>                         Ignore the source package <name>
 654 EOF
 655 }
 656
 657 parse_command();