frameworks/qt5base/files/mkspecs/linux-openwrt-g++/qmake.conf

   1 #
   2 # qmake configuration for building with linux-openwrt-g++
   3 #
   4
   5 MAKEFILE_GENERATOR      = UNIX
   6 CONFIG                 += incremental
   7 QMAKE_INCREMENTAL_STYLE = sublib
   8
   9 include(../common/linux.conf)
  10 include(../common/gcc-base-unix.conf)
  11 include(../common/g++-unix.conf)
  12
  13
  14 # modifications to gcc-base.conf (included by gcc-base-unix.conf)
  15 QMAKE_CFLAGS           += $$(TARGET_CFLAGS)
  16 QMAKE_CXXFLAGS         += $$(TARGET_CXXFLAGS)
  17 QMAKE_LFLAGS           += $$(TARGET_LDFLAGS)
  18
  19 # modifications to g++.conf
  20 QMAKE_CC                = $$(TARGET_CROSS)gcc
  21 QMAKE_CXX               = $$(TARGET_CROSS)g++
  22
  23 QMAKE_LINK_C            = $$QMAKE_CC
  24 QMAKE_LINK_C_SHLIB      = $$QMAKE_CC
  25 QMAKE_LINK              = $$QMAKE_CXX
  26 QMAKE_LINK_SHLIB        = $$QMAKE_CXX
  27
  28
  29 # modifications to linux.conf
  30 QMAKE_AR                = $$(TARGET_CROSS)ar cqs
  31 QMAKE_RANLIB            = $$(TARGET_CROSS)ranlib # QMAKE_RANLIB is set to NULL in linux.conf. Why? Not needed anymore? Set it anyway, just in case...
  32 QMAKE_OBJCOPY           = $$(TARGET_CROSS)objcopy
  33 QMAKE_NM                = $$(TARGET_CROSS)nm # whole qt5 project doesn't use $QMAKE_NM - wonder why it's defined in linux.conf at all. However better set it to ours than keep it being set to the host's version, just in case...
  34 QMAKE_STRIP             = # not used, since -no-strip is passed. Let's OpenWrt do the stripping
  35
  36
  37 load(qt_config)