convert-modeswitch.pl

   1 #!/usr/bin/perl
   2 use strict;
   3
   4 my $msg_ctr = 0;
   5 my %messages;
   6 my %devices;
   7
   8 sub add_message {
   9         my $msg = shift;
  10         my $val = $messages{$msg};
  11
  12         defined($val) or do {
  13                 $val = $msg_ctr++;
  14                 $messages{$msg} = $val;
  15         };
  16
  17         return $val;
  18 }
  19
  20 sub add_device($) {
  21         my $id = shift;
  22         my $dev = {};
  23         my $match;
  24
  25         $id =~ /^(\w{4}:\w{4})(:.*)?/ or do {
  26                 warn "Invalid device ID string $id\n";
  27                 return $dev;
  28         };
  29
  30         $id = $1;
  31         $match = $2 or $match = "*";
  32
  33         $devices{$id} or $devices{$id} = {};
  34         $devices{$id}->{$match} = $dev;
  35
  36         return $dev;
  37 }
  38
  39 sub add_hex {
  40         $_[0] =~ s/^0x//;
  41         return hex($_[0]);
  42 }
  43
  44 sub add_mode {
  45         $_[1] =~ s/^(\w+)Mode$/$1/;
  46         return $_[1];
  47 }
  48
  49 my $hex_option = [ undef, \&add_hex ];
  50 my $msg_option = [ undef, \&add_message ];
  51 my $mode_option = [ "Mode", \&add_mode ];
  52 my %options = (
  53         TargetVendor => $hex_option,
  54         TargetProductList => [ "TargetProduct", sub { return [ map(hex,split(/,/, $_[0])) ]; } ],
  55         TargetProduct => [ "TargetProduct", sub { return [ hex($_[0]) ]; } ],
  56         TargetClass => $hex_option,
  57         MessageContent => $msg_option,
  58         MessageContent2 => $msg_option,
  59         MessageContent3 => $msg_option,
  60         WaitBefore => [ ],
  61         DetachStorageOnly => [ ],
  62         MBIM => $mode_option,
  63         HuaweiMode => $mode_option,
  64         HuaweiNewMode => $mode_option,
  65         SierraMode => $mode_option,
  66         SonyMode => $mode_option,
  67         QisdaMode => $mode_option,
  68         GCTMode => $mode_option,
  69         KobilMode => $mode_option,
  70         SequansMode => $mode_option,
  71         MobileActionMode => $mode_option,
  72         CiscoMode => $mode_option,
  73         StandardEject => $mode_option,
  74         NoDriverLoading => [],
  75         MessageEndpoint => $hex_option,
  76         ReleaseDelay => [],
  77         NeedResponse => [],
  78         ResponseEndpoint => $hex_option,
  79         ResetUSB => [],
  80         InquireDevice => [],
  81         CheckSuccess => $hex_option,
  82         Interface => $hex_option,
  83         Configuration => $hex_option,
  84         AltSetting => $hex_option,
  85 );
  86
  87 sub parse_file($) {
  88         my $file = shift;
  89         my $id;
  90
  91         $id = $file;
  92         $file =~ /\/?([^\/]+)$/ and $id = $1;
  93
  94         my $dev = add_device($id);
  95
  96         open FILE, "<$file" or die "Cannot open file '$file'\n";
  97         while (<FILE>) {
  98                 chomp;
  99                 s/^\s*(.+?)\s*$/$1/;
 100                 s/#.+$//;
 101                 next unless /\w/;
 102                 /(\w+)\s*=\s*(.+)\s*/ or do {
 103                         warn "Invalid Line: $_";
 104                         next;
 105                 };
 106
 107                 my ($var, $val) = ($1, $2);
 108                 $val =~ s/^"(.+)"$/$1/;
 109
 110                 my $opt = $options{$var};
 111                 $opt or do {
 112                         warn "Unrecognized option $var in file $file\n";
 113                         next;
 114                 };
 115
 116                 $opt->[1] and $val = &{$opt->[1]}($val, $var);
 117                 $opt->[0] and $var = $opt->[0];
 118                 $dev->{$var} = $val;
 119         }
 120 }
 121
 122 foreach my $file (@ARGV) {
 123         parse_file $file;
 124 }
 125
 126 sub json_chr {
 127         my $chr = shift;
 128
 129         $chr eq "\b" and return "\\b";
 130         $chr eq "\n" and return "\\n";
 131         $chr eq "\r" and return "\\r";
 132         $chr eq "\t" and return "\\t";
 133         $chr eq "\\" and return "\\\\";
 134         $chr eq "\"" and return "\\\"";
 135         $chr eq '/' and return "\\/";
 136         return sprintf("\\u%04x", ord($chr));
 137 };
 138
 139 sub json_str {
 140         $_[0] =~ s/([\x00- \/"\\])/json_chr($1)/eg;
 141         return $_[0];
 142 }
 143
 144 sub json_val($$) {
 145         my ($val, $type) = (shift, shift);
 146         $type eq 'bool' and $val = $val > 0 ? "true" : "false";
 147         $type eq 'string' and $val = "\"$val\"";
 148         return $val;
 149 }
 150
 151 sub dev_opt {
 152         my ($val, $name, $type, $sep) = (shift, shift, shift, shift);
 153         return unless defined($val);
 154         if ($type =~ /array:(.+)/) {
 155                 $type = $1;
 156                 my @val = @$val;
 157                 undef $val;
 158                 foreach my $elem (@val) {
 159                         my $json = json_val($elem, $type);
 160                         next unless defined $json;
 161                         if (defined $val) {
 162                                 $val = "$val, $json"
 163                         } else {
 164                                 $val = $json;
 165                         }
 166                 }
 167                 $val = "[ $val ]";
 168         } else {
 169                 $val = json_val($val, $type);
 170         }
 171         print "$$sep\t\t\t\t\"".json_str($name)."\": $val";
 172         $$sep = ",\n";
 173 }
 174
 175 print <<EOF;
 176 {
 177         "messages" : [
 178 EOF
 179 my $suffix = "";
 180 foreach my $msg (sort { $messages{$a} <=> $messages{$b} } keys %messages) {
 181         print "$suffix\t\t\"".json_str($msg)."\"";
 182         $suffix = ",\n";
 183 }
 184 print <<EOF;
 185
 186         ],
 187
 188         "devices" : {
 189 EOF
 190 my $dev_sep = "";
 191 foreach my $devid (sort keys %devices) {
 192         my $dev = $devices{$devid};
 193
 194         print "$dev_sep\t\t\"".json_str($devid)."\": {\n";
 195         $dev_sep = ",\n";
 196
 197         my $match_sep = "";
 198         foreach my $match (sort keys %$dev) {
 199                 my $cur = $dev->{$match};
 200                 my $sep = "";
 201
 202                 print "$match_sep\t\t\t\"".json_str($match)."\": {\n";
 203                 $match_sep = ",\n";
 204
 205                 dev_opt($cur->{TargetVendor}, "t_vendor", "int", \$sep);
 206                 dev_opt($cur->{TargetProduct}, "t_product", "array:int", \$sep);
 207                 dev_opt($cur->{TargetClass}, "t_class", "int", \$sep);
 208                 dev_opt($cur->{DetachStorageOnly}, "detach_storage", "bool", \$sep);
 209                 dev_opt($cur->{Mode}, "mode", "string", \$sep);
 210                 dev_opt($cur->{NoDriverLoading}, "no_driver", "bool", \$sep);
 211                 dev_opt($cur->{MessageEndpoint}, "msg_endpoint", "int", \$sep);
 212                 my $msg = [
 213                         $cur->{MessageContent},
 214                         $cur->{MessageContent2},
 215                         $cur->{MessageContent3}
 216                 ];
 217                 dev_opt($msg, "msg", "array:int", \$sep);
 218                 dev_opt($cur->{WaitBefore}, "wait", "int", \$sep);
 219                 dev_opt($cur->{ReleaseDelay}, "release_delay", "int", \$sep);
 220                 dev_opt($cur->{NeedResponse}, "response", "bool", \$sep);
 221                 dev_opt($cur->{ResponseEndpoint}, "response_endpoint", "int", \$sep);
 222                 dev_opt($cur->{ResetUSB}, "reset", "bool", \$sep);
 223                 dev_opt($cur->{InquireDevice}, "inquire", "int", \$sep);
 224                 dev_opt($cur->{CheckSuccess}, "check", "bool", \$sep);
 225                 dev_opt($cur->{Interface}, "interface", "int", \$sep);
 226                 dev_opt($cur->{Configuration}, "config", "int", \$sep);
 227                 dev_opt($cur->{AltSetting}, "alt", "int", \$sep);
 228                 print "\n\t\t\t}";
 229         }
 230         print "\n\t\t}"
 231 }
 232 print <<EOF;
 233
 234         }
 235 }
 236 EOF